PUBG Script

This is a discussion on PUBG Script within the PUBG board part of the Hot Games category; Here is a AHK script that makes PlayerUnknownBattlegrounds more comfortable to play. You need AHK to run the script and ...

Results 1 to 5 of 5
  1. #1
    BadshaX's Avatar
    BadshaX is offline Advanced Hacker

    Array
    Join Date
    Mar 2016
    Posts
    285
    Mentioned
    6 Post(s)
    Tagged
    0 Thread(s)
    Rep Power
    3
    Reputation
    37

    Lightbulb PUBG Script

    Here is a AHK script that makes PlayerUnknownBattlegrounds more comfortable to play.

    You need AHK to run the script and the script will only work in (Window) or (Windows fullscreen)
    You can toggle Pause/Play script with Pause Button.


    Features:
    - CrouchJump
    - AutoFire
    - Compensation
    - ADS (Fast Aiming)


    Crouch Jump
    Crouch jumping, aka super jump, before you had to press Space and C exactly at the same time, that makes it quite difficult... With this script you can jump normally with single Space press, and super jump if you press and hold Space. So, single press = normal jump, hold space = super jump. Also keeps crouching 0.5 seconds to improve the jump. This will be useful at least until vaulting is released.
    [Toggle: NumPad 0]


    AutoFire
    It'll allow you to shot in Full Auto mode for all semi automatic weapons (e.g. M16, SKS, Mini-14 and Pistols) Only works while holding aim (holding right click) so you'll be able to throw grenades.
    [Toggle: CapsLock]




    Compensation
    Moves the mouse down to compensate recoil, by default is set to 8, which is optimal for short/mid range. Also it only works while holding aim, to allow you throw grenades properly.
    [Toggle: NumPad Dot]
    [Adds Compensation: NumPad +]
    [Substracts Compensation: NumPad -]


    ADS (Fast Aiming)
    You'll be able to aim from the ads while holding right click instead of clicking twice. If enabled, clicks once and clicks again when button is released. If not, just keeps holding until button is released.
    [Toggle: Mouse 5 Button]

    Code:
    ;#########################;#     Configuration     #
    ;#########################
    #NoEnv ; Improves performance and compatibility with future AHK updates.
    #SingleInstance force ; It allows to run only one at the same time.
    SetTitleMatchMode, 2 ; Matching for window title.
    #ifwinactive, PLAYERUNKNOWN'S BATTLEGROUNDS ; enabled only when in PUBG.
    
    
    ;#####################
    ;#     Variables     #
    ;#####################
    isMouseShown() ; To suspend script when mouse is visible.
    
    
    ADS = 0 ; Var for fast aiming.
    CrouchJump = 1 ; Var for crouch when jumping.
    AutoFire = 0 ; Var for autofiring.
    Compensation = 1 ; Var for compensation when autofiring.
    compVal = 8 ; Compensation value. (Default: 8, optimal for short/mid range)
    
    
    ;########################################
    ;#     Suspends if mouse is visible     #
    ;########################################
    
    
    
    
    isMouseShown() ; It suspends the script when mouse is visible (map, inventory, menu).
    {
      StructSize := A_PtrSize + 16
      VarSetCapacity(InfoStruct, StructSize)
      NumPut(StructSize, InfoStruct)
      DllCall("GetCursorInfo", UInt, &InfoStruct)
      Result := NumGet(InfoStruct, 8)
    
    
      if Result > 1
        Return 1
      else
        Return 0
    }
    Loop
    {
      if isMouseShown() ==1
        Suspend On
      else
        Suspend Off
        Sleep 1
    }
    
    
    
    
    ;#######################
    ;#     Fast Aiming     #
    ;#######################
    
    
    *RButton:: ; Fast Aiming
    if ADS = 1
    { ; If enabled, clicks once and clicks again when button is released.
      SendInput {RButton}
      SendInput {RButton Down}
      KeyWait, RButton
      SendInput {RButton Up}
    } else { ; If not, just keeps holding until button is released.
      SendInput {RButton Down}
      KeyWait, RButton
      SendInput {RButton Up}
    }
    Return
    
    
    ;######################
    ;#     CrouchJump     #
    ;######################
    *$Space::
    if CrouchJump = 1
    {
      KeyWait, Space, T0.08
      If ErrorLevel = 1  ; If Space is holding then jumps and crouch.
      {
        SendInput {Space}{c down}
        Sleep 500 ; And keeps crouching 0.5 seconds to improve the jump.
        SendInput {c up}
      } else { ; Else just jumps.
        SendInput {Space}
      }
    } else
      SendInput {Space}
    Return
    
    
    ;####################
    ;#     AutoFire     #
    ;####################
    ~$*LButton:: ; AutoFire
    If GetKeyState("RButton") ; Only works while holding aim (so you'll be able to throw grenades)
    {
      if (AutoFire = 1 || Compensation = 1)
      {
          Loop ; If AutoFire or Compensation are activated loops this section.
          {
            Sleep 1
              GetKeyState, LButton, LButton, P
              if LButton = U ; If Left Click is released then breaks the loop.
                  Break
              If AutoFire = 1 ; If enabled keeps clicking.
                  MouseClick, Left,,, 1
              if Compensation = 1 ; If enabled, call to Compensation.
                mouseXY(0, compVal)
            ; Gosub, RandomSleep ; Call to RandomSleep. (Currently unstable)
            Sleep 25
          }
      }
    }
    Return
    RandomSleep: ; Random timing between clicks, just in case.
      Random, random, 14, 25
      Sleep %random%-5
    Return
    
    
    
    
    
    
    
    
    ;########################
    ;#     Compensation     #
    ;########################
    
    
    mouseXY(x,y) ; Moves the mouse down to compensate recoil (value in compVal var).
    {
      DllCall("mouse_event",uint,1,int,x,int,y,uint,0,int,0)
    }
    
    
    ;###################
    ;#     ToolTip     #
    ;###################
    
    
    ToolTip(Text) ; Function to show a tooltip when activating, deactivating or changing values.
    {
      activeMonitorInfo(X, Y, Width, Height) ; Get current resolution
      xPos := Width / 2 - 50
      yPos := Height / 2 + (Height / 10)
    
    
      ToolTip, %Text%, xPos, yPos ; Tooltips are shown under crosshair.
      SetTimer, RemoveToolTip, 1300 ; Removes tooltip after 1.3 seconds.
      return
      RemoveToolTip:
      SetTimer, RemoveToolTip, Off
      ToolTip
      Return
    }
    
    
    /*
    ToolTip(Text, Color) {
      activeMonitorInfo(X, Y, Width, Height) ; Get current resolution
      xPos := Width / 2 - 30
      yPos := Height / 2 + (Height / 10)
    ;SoundPlay, *64  ; Simple beep. If the sound card is not available, the sound is generated using the speaker.
      CustomColor = EEAA99
      Gui +LastFound +AlwaysOnTop -Caption +ToolWindow
      Gui, Color, %CustomColor%
      Gui, Font, s16, Arial
      Gui, Add, Text, c%Color% , %Text%
      WinSet, TransColor, %CustomColor%
      Gui, Show, x%xPos% y%yPos% NoActivate
      Sleep, 600
      Gui, Destroy
      Return
    }
    */
    
    
    ;####################################
    ;#     Hotkeys to change values     #
    ;####################################
    
    
    ; Toggles
    Pause::
        Suspend
        if (A_IsSuspended)
      {
            ToolTip("SCRIPT OFF")
        } else
            ToolTip("SCRIPT ON")
    return
    *XButton2::( ADS = 0 ? (ADS := 1,ToolTip("ADS ON")) : (ADS := 0,ToolTip("ADS OFF")) ) ; ADS Toggle
    *NumPadDot::( Compensation = 0 ? (Compensation := 1,ToolTip("Compensation ON")) : (Compensation := 0,ToolTip("Compensation OFF")) ) ; Compensation Toggle
    *NumPad0::( CrouchJump = 0 ? (CrouchJump := 1,ToolTip("CrouchJump ON")) : (CrouchJump := 0,ToolTip("CrouchJump OFF")) ) ; CrouchJump Toggle
    
    
    ~CapsLock:: ; AutoFire Toggle
    if (GetKeyState("CapsLock","t")=0)
    {
      AutoFire = 0
      ToolTip("AutoFire OFF")
    } else if (GetKeyState("CapsLock","t")=1) {
      AutoFire = 1
      ToolTip("AutoFire ON")
    }
    Return
    
    
    *NumpadAdd:: ; Adds compensation.
      compVal := compVal + 2
      ToolTip("Compensation " . compVal)
    Return
    
    
    *NumpadSub:: ; Substracts compensation.
    if compVal > 0
    {
      compVal := compVal - 2
      ToolTip("Compensation " . compVal)
    }
    Return
    
    
    ;##########################
    ;#     Get Resolution     #
    ;##########################
    
    
    activeMonitorInfo( ByRef X, ByRef Y, ByRef Width,  ByRef  Height  )
    { ; Retrieves the size of the monitor, the mouse is on
    
    
        CoordMode, Mouse, Screen
        MouseGetPos, mouseX , mouseY
        SysGet, monCount, MonitorCount
        Loop %monCount%
        {     SysGet, curMon, Monitor, %a_index%
            if ( mouseX >= curMonLeft and mouseX <= curMonRight and mouseY >= curMonTop and mouseY <= curMonBottom )
                {
                    X      := curMonTop
                    y      := curMonLeft
                    Height := curMonBottom - curMonTop
                    Width  := curMonRight  - curMonLeft
                    return
                }
        }
    }
    Questions? - Just ask.
    Like it? - Smash thanks button.
    - There are no working hours for leaders

  2. The Following User Says Thank You to BadshaX For This Useful Post:


  3. #2
    hoffer's Avatar
    hoffer is offline Wannabe Member
    Array
    Join Date
    Mar 2012
    Location
    Russia>Moscow>Butovo
    Posts
    18
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Rep Power
    7
    Reputation
    1
    Hey. It still work? not banned for that?

  4. #3
    BadshaX's Avatar
    BadshaX is offline Advanced Hacker

    Array
    Join Date
    Mar 2016
    Posts
    285
    Mentioned
    6 Post(s)
    Tagged
    0 Thread(s)
    Rep Power
    3
    Reputation
    37
    Quote Originally Posted by hoffer View Post
    Hey. It still work? not banned for that?
    Battleeye started to ban for no recoil lately so use at your own risk.
    - There are no working hours for leaders

  5. #4
    BadshaX's Avatar
    BadshaX is offline Advanced Hacker

    Array
    Join Date
    Mar 2016
    Posts
    285
    Mentioned
    6 Post(s)
    Tagged
    0 Thread(s)
    Rep Power
    3
    Reputation
    37
    Status: DETECTED
    - There are no working hours for leaders

  6. #5
    Kiwath's Avatar
    Kiwath is offline Newbie
    Array
    Join Date
    Jan 2019
    Posts
    5
    Mentioned
    0 Post(s)
    Tagged
    0 Thread(s)
    Rep Power
    0
    Reputation
    0
    interesting scripts, really. I am also interested in whether there are scripts for the mobile version of PUBG?

Similar Threads

  1. [PAID OTHER] Pubg esp or more
    By kraz0r in forum Request a Hack
    Replies: 0
    Last Post: 10-01-2017, 02:15 AM
  2. [Bot/Autoit Script] PVP Honor Leeching Script
    By tschoerk in forum WoW Bots, hacks and exploits
    Replies: 36
    Last Post: 11-30-2011, 11:00 PM
  3. Replies: 1
    Last Post: 08-24-2010, 03:38 PM
  4. Replies: 4
    Last Post: 08-23-2009, 10:38 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •